iolite/build.gradle.kts at develop · ysknsid25/iolite · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
import io.gitlab.arturbosch.detekt.Detekt
import cl.franciscosolis.sonatypecentralupload.SonatypeCentralUploadTask


plugins {
    kotlin("jvm") version "2.0.21"
    id("io.gitlab.arturbosch.detekt") version "1.23.8"
    id("org.jetbrains.kotlinx.kover") version "0.9.1"
    id("org.jetbrains.dokka") version "2.0.0"
    `maven-publish`
    id("cl.franciscosolis.sonatype-central-upload") version "1.0.3"
}

group = "io.github.ysknsid25.iolite"
version = "beta-v2"

repositories {
    mavenCentral()
}

dependencies {
    testImplementation(kotlin("test"))
    testImplementation("com.lemonappdev:konsist:0.17.3")
    testImplementation("org.junit.jupiter:junit-jupiter-api:5.10.0")
    testImplementation("org.junit.jupiter:junit-jupiter-params:5.10.0")
    testRuntimeOnly("org.junit.jupiter:junit-jupiter-engine:5.10.0")
    detektPlugins("io.gitlab.arturbosch.detekt:detekt-formatting:1.23.1")
}

java {
    withSourcesJar()
    withJavadocJar()
}

detekt{
    config.setFrom("${rootProject.projectDir}/config/detekt/detekt.yml")
    buildUponDefaultConfig = true
    autoCorrect = true
}

publishing {
    publications {
        register<MavenPublication>("maven") {
            pom {
                name.set(project.name)
                description.set("A generic Value Object library inspired by Zod for Kotlin")
                url.set("https://github.com/ysknsid25/iolite")
                licenses {
                    license {
                        name.set("MIT License")
                        url.set("https://github.com/ysknsid25/iolite/blob/master/LISENCE")
                        distribution.set("repo")
                    }
                }
                developers {
                    developer {
                        id.set("ysknsid25")
                        name.set("Kanon")
                        email.set("inorinrinrin1202@gmail.com")
                    }
                }
                scm {
                    url.set("https://github.com/ysknsid25/iolite")
                }
            }
            artifact("${rootProject.projectDir}/build/kotlinToolingMetadata/kotlin-tooling-metadata.json") {
                extension = "json"
                builtBy(tasks.named("buildKotlinToolingMetadata"))
            }
        }
    }
}

tasks.named<SonatypeCentralUploadTask>("sonatypeCentralUpload") {
    dependsOn("jar", "sourcesJar", "javadocJar", "buildKotlinToolingMetadata", "generatePomFileForMavenPublication")

    username = System.getenv("SONATYPE_CENTRAL_USERNAME")
    password = System.getenv("SONATYPE_CENTRAL_PASSWORD")

    archives = files(
        tasks.named("jar"),
        tasks.named("sourcesJar"),
        tasks.named("javadocJar"),
    )
    pom = file(
        tasks.named("generatePomFileForMavenPublication").get().outputs.files.single()
    )

    signingKey = System.getenv("PGP_SIGNING_KEY")
    signingKeyPassphrase = System.getenv("PGP_SIGNING_KEY_PASSPHRASE")
}

tasks.dokkaHtml.configure {
    outputDirectory.set(file("${rootProject.projectDir}/docs"))
}

tasks.test {
    useJUnitPlatform()
}

tasks {
    withType<Detekt> {
        reports {
            html.required.set(true)
            html.outputLocation.set(file("${rootProject.projectDir}/reports/detekt.html"))
            xml.required.set(false)
            txt.required.set(false)
            sarif.required.set(false)
        }
    }
}