feat: multiple versions for the timescaledb-apache extension

Author: yvan-sraka

.gitignore

@@ -25,3 +25,5 @@ result*
 
 db/schema.sql
 common-nix.vars.pkr.hcl
+
+.envrc

flake.nix

@@ -129,8 +129,7 @@
         # go through the upstream release engineering process.
         ourExtensions = [
           ./nix/ext/rum.nix
-          ./nix/ext/timescaledb.nix
-          ./nix/ext/timescaledb-2.9.1.nix
+          ./nix/ext/timescaledb-apache.nix
           ./nix/ext/pgroonga.nix
           ./nix/ext/index_advisor.nix
           ./nix/ext/wal2json.nix
@@ -161,16 +160,13 @@
           ./nix/ext/plv8.nix
         ];
 
-        #Where we import and build the orioledb extension, we add on our custom extensions
-        # plus the orioledb option
-        #we're not using timescaledb or plv8 in the orioledb-17 version or pg 17 of supabase extensions
+        # Where we import and build the orioledb extension, we add on our
+        # custom extensions plus the orioledb option. We're not using
+        # timescaledb or plv8 in the orioledb-17 version or pg 17 of supabase
+        # extensions
         orioleFilteredExtensions = builtins.filter
-          (
-            x:
-            x != ./nix/ext/timescaledb.nix &&
-            x != ./nix/ext/timescaledb-2.9.1.nix &&
-            x != ./nix/ext/plv8.nix
-        ) ourExtensions;
+          (x: x != ./nix/ext/timescaledb-apache.nix && x != ./nix/ext/plv8.nix)
+          ourExtensions;
 
         orioledbExtensions = orioleFilteredExtensions ++ [ ./nix/ext/orioledb.nix ];
         dbExtensions17 = orioleFilteredExtensions;

nix/ext/timescaledb-2.9.1.nix

@@ -0,0 +1,83 @@
+{ pkgs, lib, stdenv, fetchFromGitHub, cmake, postgresql, openssl, libkrb5 }:
+
+let
+  pname = "timescaledb-apache";
+  build = version: hash: revision:
+    stdenv.mkDerivation rec {
+      inherit pname version;
+
+      nativeBuildInputs = [ cmake ];
+      buildInputs = [ postgresql openssl libkrb5 ];
+
+      src = fetchFromGitHub {
+        owner = "timescale";
+        repo = "timescaledb";
+        rev = version;
+        inherit hash;
+      };
+
+      cmakeFlags = [
+        "-DSEND_TELEMETRY_DEFAULT=OFF"
+        "-DREGRESS_CHECKS=OFF"
+        "-DTAP_CHECKS=OFF"
+        "-DAPACHE_ONLY=1"
+      ] ++ lib.optionals stdenv.isDarwin [ "-DLINTER=OFF" ];
+
+      # Fix the install phase which tries to install into the pgsql extension dir,
+      # and cannot be manually overridden. This is rather fragile but works OK.
+      postPatch = ''
+        for x in CMakeLists.txt sql/CMakeLists.txt; do
+          if [ -f "$x" ]; then
+            substituteInPlace "$x" \
+              --replace 'DESTINATION "''${PG_SHAREDIR}/extension"' "DESTINATION \"$out/share/postgresql/extension\""
+          fi
+        done
+
+        for x in src/CMakeLists.txt src/loader/CMakeLists.txt tsl/src/CMakeLists.txt; do
+          if [ -f "$x" ]; then
+            substituteInPlace "$x" \
+              --replace 'DESTINATION ''${PG_PKGLIBDIR}' "DESTINATION \"$out/lib\""
+          fi
+        done
+      '';
+
+      # timescaledb-$VERSION.so already exists in the lib directory
+      # we have no need for the timescaledb.so or control file
+      postInstall = ''
+        rm -f $out/lib/timescaledb.so
+        rm -f $out/share/postgresql/extension/timescaledb.control
+      '';
+
+      meta = with lib; {
+        description =
+          "Scales PostgreSQL for time-series data via automatic partitioning across time and space";
+        homepage = "https://www.timescale.com/";
+        changelog =
+          "https://github.com/timescale/timescaledb/blob/${version}/CHANGELOG.md";
+        license = licenses.postgresql;
+        inherit (postgresql.meta) platforms;
+      };
+    };
+
+  allVersions =
+    (builtins.fromJSON (builtins.readFile ./versions.json)).timescaledb-apache;
+  supportedVersions = lib.filterAttrs (_: value:
+    builtins.elem (lib.versions.major postgresql.version) value.postgresql)
+    allVersions;
+  versions = lib.naturalSort (lib.attrNames supportedVersions);
+  latestVersion = lib.last versions;
+  numberOfVersions = builtins.length versions;
+  packages = builtins.attrValues
+    (lib.mapAttrs (name: value: build name value.hash (value.revision or name))
+      supportedVersions);
+in pkgs.buildEnv {
+  name = pname;
+  paths = packages;
+  pathsToLink = [ "/lib" "/share/postgresql/extension" ];
+  passthru = {
+    inherit versions numberOfVersions;
+    pname = "${pname}-all";
+    version = "multi-" + lib.concatStringsSep "-"
+      (map (v: lib.replaceStrings [ "." ] [ "-" ] v) versions);
+  };
+}