Fix text clipping

Summary:
Gate the iOS compressed text adjustment behind `enableIOSCompressedTextFrameAdjustment`, expand the paragraph text drawing frame when compressed glyph bounds exceed the view bounds, and center glyph drawing for explicit line heights shorter than the font metrics.

Changelog: [internal]

Differential Revision: D110430304

Author: sbuggay

packages/react-native/React/Fabric/Mounting/ComponentViews/Text/RCTParagraphComponentView.mm

@@ -9,6 +9,7 @@
 #import "RCTParagraphComponentAccessibilityProvider.h"
 
 #import <MobileCoreServices/UTCoreTypes.h>
+#import <react/featureflags/ReactNativeFeatureFlags.h>
 #import <react/renderer/components/text/ParagraphComponentDescriptor.h>
 #import <react/renderer/components/text/ParagraphProps.h>
 #import <react/renderer/components/text/ParagraphState.h>
@@ -24,6 +25,14 @@
 
 using namespace facebook::react;
 
+@interface RCTTextLayoutManager (RCTParagraphComponentViewPrivate)
+
+- (CGFloat)drawingHeightForAttributedString:(facebook::react::AttributedString)attributedString
+                        paragraphAttributes:(facebook::react::ParagraphAttributes)paragraphAttributes
+                                       size:(CGSize)size;
+
+@end
+
 // ParagraphTextView is an auxiliary view we set as contentView so the drawing
 // can happen on top of the layers manipulated by RCTViewComponentView (the parent view)
 @interface RCTParagraphTextView : UIView
@@ -149,7 +158,30 @@ - (void)layoutSubviews
 {
   [super layoutSubviews];
 
-  _textView.frame = self.bounds;
+  CGRect textFrame = self.bounds;
+  if (!ReactNativeFeatureFlags::enableIOSCompressedTextFrameAdjustment()) {
+    _textView.frame = textFrame;
+    return;
+  }
+
+  if (_textView.state && textFrame.size.height > 0) {
+    const auto &stateData = _textView.state->getData();
+    auto textLayoutManager = stateData.layoutManager.lock();
+    if (textLayoutManager) {
+      RCTTextLayoutManager *nativeTextLayoutManager =
+          (RCTTextLayoutManager *)unwrapManagedObject(textLayoutManager->getNativeTextLayoutManager());
+      CGFloat drawingHeight = [nativeTextLayoutManager drawingHeightForAttributedString:stateData.attributedString
+                                                                    paragraphAttributes:_paragraphAttributes
+                                                                                   size:textFrame.size];
+      if (drawingHeight > textFrame.size.height) {
+        CGFloat extraHeight = drawingHeight - textFrame.size.height;
+        textFrame.origin.y -= extraHeight / 2.0;
+        textFrame.size.height = drawingHeight;
+      }
+    }
+  }
+
+  _textView.frame = textFrame;
 }
 
 #pragma mark - Accessibility
@@ -194,7 +226,7 @@ - (NSArray *)accessibilityElements
     if (textLayoutManager) {
       RCTTextLayoutManager *nativeTextLayoutManager =
           (RCTTextLayoutManager *)unwrapManagedObject(textLayoutManager->getNativeTextLayoutManager());
-      CGRect frame = RCTCGRectFromRect(_layoutMetrics.getContentFrame());
+      CGRect frame = self.bounds;
       _accessibilityProvider =
           [[RCTParagraphComponentAccessibilityProvider alloc] initWithString:data.attributedString
                                                                layoutManager:nativeTextLayoutManager
@@ -268,7 +300,7 @@ - (SharedTouchEventEmitter)touchEventEmitterAtPoint:(CGPoint)point
 
   RCTTextLayoutManager *nativeTextLayoutManager =
       (RCTTextLayoutManager *)unwrapManagedObject(textLayoutManager->getNativeTextLayoutManager());
-  CGRect frame = RCTCGRectFromRect(_layoutMetrics.getContentFrame());
+  CGRect frame = self.bounds;
 
   auto eventEmitter = [nativeTextLayoutManager getEventEmitterWithAttributeString:stateData.attributedString
                                                               paragraphAttributes:_paragraphAttributes
@@ -404,7 +436,7 @@ - (void)drawRect:(CGRect)rect
   RCTTextLayoutManager *nativeTextLayoutManager =
       (RCTTextLayoutManager *)unwrapManagedObject(textLayoutManager->getNativeTextLayoutManager());
 
-  CGRect frame = RCTCGRectFromRect(_layoutMetrics.getContentFrame());
+  CGRect frame = self.bounds;
 
   [nativeTextLayoutManager drawAttributedString:stateData.attributedString
                             paragraphAttributes:_paragraphAttributes

packages/react-native/ReactCommon/react/renderer/textlayoutmanager/platform/ios/react/renderer/textlayoutmanager/RCTAttributedTextUtils.mm

@@ -369,7 +369,7 @@ static void RCTApplyBaselineOffsetForRange(NSMutableAttributedString *attributed
                             maximumFontLineHeight = MAX(font.lineHeight, maximumFontLineHeight);
                           }];
 
-  if (maximumLineHeight < maximumFontLineHeight) {
+  if (maximumLineHeight < maximumFontLineHeight && !ReactNativeFeatureFlags::enableIOSCompressedTextFrameAdjustment()) {
     return;
   }
 

packages/react-native/ReactCommon/react/renderer/textlayoutmanager/platform/ios/react/renderer/textlayoutmanager/RCTTextLayoutManager.mm

@@ -68,6 +68,42 @@ - (TextMeasurement)measureAttributedString:(AttributedString)attributedString
                        layoutConstraints:layoutConstraints];
 }
 
+- (CGFloat)drawingHeightForAttributedString:(AttributedString)attributedString
+                        paragraphAttributes:(ParagraphAttributes)paragraphAttributes
+                                       size:(CGSize)size
+{
+  if (!ReactNativeFeatureFlags::enableIOSCompressedTextFrameAdjustment()) {
+    return size.height;
+  }
+
+  NSTextStorage *textStorage = [self
+      _textStorageAndLayoutManagerWithAttributesString:[self _nsAttributedStringFromAttributedString:attributedString]
+                                   paragraphAttributes:paragraphAttributes
+                                                  size:size];
+  NSLayoutManager *layoutManager = textStorage.layoutManagers.firstObject;
+  NSTextContainer *textContainer = layoutManager.textContainers.firstObject;
+  [layoutManager ensureLayoutForTextContainer:textContainer];
+
+  NSRange glyphRange = [layoutManager glyphRangeForTextContainer:textContainer];
+  __block CGFloat maximumLineHeight = 0;
+  [textStorage enumerateAttribute:NSParagraphStyleAttributeName
+                          inRange:NSMakeRange(0, textStorage.length)
+                          options:NSAttributedStringEnumerationLongestEffectiveRangeNotRequired
+                       usingBlock:^(NSParagraphStyle *paragraphStyle, __unused NSRange range, __unused BOOL *stop) {
+                         if (paragraphStyle != nil) {
+                           maximumLineHeight = MAX(paragraphStyle.maximumLineHeight, maximumLineHeight);
+                         }
+                       }];
+  if (maximumLineHeight == 0 || glyphRange.length == 0) {
+    return size.height;
+  }
+
+  CGRect glyphBounds = [layoutManager boundingRectForGlyphRange:glyphRange inTextContainer:textContainer];
+  CGFloat glyphHeight = CGRectGetMaxY(glyphBounds) - MIN(glyphBounds.origin.y, 0);
+  CGFloat drawingHeight = MAX(size.height, glyphHeight);
+  return drawingHeight;
+}
+
 - (void)drawAttributedString:(AttributedString)attributedString
          paragraphAttributes:(ParagraphAttributes)paragraphAttributes
                        frame:(CGRect)frame
@@ -90,8 +126,27 @@ - (void)drawAttributedString:(AttributedString)attributedString
 
   [self processTruncatedAttributedText:textStorage textContainer:textContainer layoutManager:layoutManager];
 
-  [layoutManager drawBackgroundForGlyphRange:glyphRange atPoint:frame.origin];
-  [layoutManager drawGlyphsForGlyphRange:glyphRange atPoint:frame.origin];
+  CGPoint textDrawPoint = frame.origin;
+  if (ReactNativeFeatureFlags::enableIOSCompressedTextFrameAdjustment() && glyphRange.length > 0) {
+    __block CGFloat maximumDrawLineHeight = 0;
+    [textStorage enumerateAttribute:NSParagraphStyleAttributeName
+                            inRange:NSMakeRange(0, textStorage.length)
+                            options:NSAttributedStringEnumerationLongestEffectiveRangeNotRequired
+                         usingBlock:^(NSParagraphStyle *paragraphStyle, __unused NSRange range, __unused BOOL *stop) {
+                           if (paragraphStyle != nil) {
+                             maximumDrawLineHeight = MAX(paragraphStyle.maximumLineHeight, maximumDrawLineHeight);
+                           }
+                         }];
+    if (maximumDrawLineHeight > 0) {
+      CGRect finalGlyphBounds = [layoutManager boundingRectForGlyphRange:glyphRange inTextContainer:textContainer];
+      if (finalGlyphBounds.origin.y < 0) {
+        textDrawPoint.y += (frame.size.height - finalGlyphBounds.size.height) / 2.0 - finalGlyphBounds.origin.y;
+      }
+    }
+  }
+
+  [layoutManager drawBackgroundForGlyphRange:glyphRange atPoint:textDrawPoint];
+  [layoutManager drawGlyphsForGlyphRange:glyphRange atPoint:textDrawPoint];
 
 #if TARGET_OS_MACCATALYST
   CGContextRestoreGState(context);
@@ -504,7 +559,8 @@ - (TextMeasurement)_measureTextStorage:(NSTextStorage *)textStorage
                                  }
                                }];
 
-  CGSize size = [layoutManager usedRectForTextContainer:textContainer].size;
+  CGRect usedBounds = [layoutManager usedRectForTextContainer:textContainer];
+  CGSize size = usedBounds.size;
 
   if (textDidWrap) {
     size.width = textContainer.size.width;