Merge branch 'PHP-8.3' into PHP-8.4

Author: petk

cmake/cmake/Flags.cmake

@@ -500,7 +500,7 @@ endif()
 ################################################################################
 
 # Align segments on huge page boundary.
-include(PHP/CheckSegmentsAlignment)
+include(${CMAKE_CURRENT_LIST_DIR}/checks/CheckSegmentsAlignment.cmake)
 
 check_linker_flag(C LINKER:/verbose PHP_HAS_VERBOSE_LINKER_FLAG_C)
 if(PHP_HAS_VERBOSE_LINKER_FLAG_C)

cmake/cmake/checks/CheckSegmentsAlignment.cmake

@@ -0,0 +1,107 @@
+#[=============================================================================[
+This module checks linker support for aligning .text segments on huge page
+boundary.
+
+Usually, the CheckLinkerFlag module is used to check linker flags, however due
+to the LLD bug present in versions before 18.1 the run check needs to be
+performed. When cross-compiling, the CheckLinkerFlag module is used and the LDD
+bug bypassed for versions prior to 18.1.
+
+See also:
+- https://github.com/llvm/llvm-project/issues/57618
+- https://releases.llvm.org/18.1.0/tools/lld/docs/ReleaseNotes.html
+- https://bugs.php.net/79092
+- https://github.com/php/php-src/pull/5123
+#]=============================================================================]
+
+include_guard(GLOBAL)
+
+include(CheckLinkerFlag)
+include(CheckSourceRuns)
+include(CMakePushCheckState)
+
+message(
+  CHECK_START
+  "Checking linker support for aligning segments on huge page boundary"
+)
+
+if(
+  NOT CMAKE_SYSTEM_NAME STREQUAL "Linux"
+  AND NOT CMAKE_SYSTEM_PROCESSOR MATCHES "^(i[3456]86.*|x86_64)$"
+)
+  message(CHECK_FAIL "no")
+  return()
+endif()
+
+if(CMAKE_CROSSCOMPILING AND NOT CMAKE_CROSSCOMPILING_EMULATOR)
+  if(
+    CMAKE_C_COMPILER_LINKER_ID STREQUAL "LLD"
+    AND CMAKE_C_COMPILER_LINKER_VERSION
+    AND CMAKE_C_COMPILER_LINKER_VERSION VERSION_LESS 18.1
+  )
+    set(PHP_HAS_ALIGNMENT_FLAGS_C FALSE)
+  endif()
+
+  if(
+    CMAKE_CXX_COMPILER_LINKER_ID STREQUAL "LLD"
+    AND CMAKE_CXX_COMPILER_LINKER_VERSION
+    AND CMAKE_CXX_COMPILER_LINKER_VERSION VERSION_LESS 18.1
+  )
+    set(PHP_HAS_ALIGNMENT_FLAGS_CXX FALSE)
+  endif()
+endif()
+
+# Checks given linker flags and adds them to the php_config interface target.
+function(_php_check_segments_alignment lang flags result)
+  if(NOT DEFINED ${result})
+    cmake_push_check_state(RESET)
+      set(CMAKE_REQUIRED_QUIET TRUE)
+
+      if(CMAKE_CROSSCOMPILING AND NOT CMAKE_CROSSCOMPILING_EMULATOR)
+        check_linker_flag(${lang} "${flags}" ${result})
+      else()
+        set(CMAKE_REQUIRED_LINK_OPTIONS ${flags})
+        check_source_runs(${lang} [[int main(void) { return 0; }]] ${result})
+      endif()
+    cmake_pop_check_state()
+  endif()
+
+  if(${result})
+    target_link_options(
+      php_config
+      INTERFACE
+        $<$<AND:$<STREQUAL:$<TARGET_PROPERTY:TYPE>,EXECUTABLE>,$<LINK_LANGUAGE:${lang}>>:${flags}>
+    )
+  endif()
+endfunction()
+
+set(flags LINKER:-z,common-page-size=2097152 LINKER:-z,max-page-size=2097152)
+_php_check_segments_alignment(C "${flags}" PHP_HAS_ALIGNMENT_FLAGS_C)
+
+if(NOT PHP_HAS_ALIGNMENT_FLAGS_C)
+  set(flags LINKER:-z,max-page-size=2097152)
+  _php_check_segments_alignment(C "${flags}" PHP_HAS_MAX_PAGE_SIZE_C)
+endif()
+
+get_property(enabledLanguages GLOBAL PROPERTY ENABLED_LANGUAGES)
+
+if(CXX IN_LIST enabledLanguages)
+  set(flags LINKER:-z,common-page-size=2097152 LINKER:-z,max-page-size=2097152)
+  _php_check_segments_alignment(CXX "${flags}" PHP_HAS_ALIGNMENT_FLAGS_CXX)
+
+  if(NOT PHP_HAS_ALIGNMENT_FLAGS_CXX)
+    set(flags LINKER:-z,max-page-size=2097152)
+    _php_check_segments_alignment(CXX "${flags}" PHP_HAS_MAX_PAGE_SIZE_CXX)
+  endif()
+endif()
+
+if(
+  PHP_HAS_ALIGNMENT_FLAGS_C
+  OR PHP_HAS_ALIGNMENT_FLAGS_CXX
+  OR PHP_HAS_MAX_PAGE_SIZE_C
+  OR PHP_HAS_MAX_PAGE_SIZE_CXX
+)
+  message(CHECK_PASS "done")
+else()
+  message(CHECK_FAIL "no")
+endif()

cmake/cmake/modules/PHP/CheckSegmentsAlignment.cmake

@@ -19,13 +19,6 @@ set(CMAKE_FIND_ROOT_PATH "")
 # Set the exit code for the fopencookie seeker using off64_t check.
 set(PHP_HAS_COOKIE_SEEKER_OFF64_T_EXITCODE 0)
 
-# Set the exit codes for the alignment segments checks.
-# See PHP/CheckSegmentsAlignment.cmake
-set(PHP_HAS_ALIGNMENT_FLAGS_C_EXITCODE 0)
-set(PHP_HAS_MAX_PAGE_SIZE_C_EXITCODE 0)
-set(PHP_HAS_ALIGNMENT_FLAGS_CXX_EXITCODE 0)
-set(PHP_HAS_MAX_PAGE_SIZE_CXX_EXITCODE 0)
-
 # Set the exit code if flush should be called explicitly after a buffered io.
 set(PHP_HAS_FLUSHIO_EXITCODE 1)