gtk: replace Bash script with writeText and linkFarm

Author: danth

modules/gtk/theme.nix

@@ -8,77 +8,75 @@
 {
   cfg,
   colors,
+  lib,
   adw-gtk3,
-  runCommandLocal,
+  linkFarm,
+  writeText,
 }:
-runCommandLocal "stylix-gtk-theme"
-  {
-    baseCss = colors {
-      template = ./gtk.css.mustache;
-      extension = ".css";
-    };
-    inherit (cfg) extraCss;
-    parent = "${adw-gtk3}/share/themes/adw-gtk3";
-  }
-  ''
-    config="$out/etc/xdg"
-    theme="$out/share/themes/Stylix"
-
-    mkdir --parents \
-      "$config/gtk-3.0" \
-      "$config/gtk-4.0" \
-      "$theme/gtk-3.0" \
-      "$theme/gtk-4.0"
-
-    cat >"$config/gtk-3.0/settings.ini" <<EOF
-    [Settings]
-    gtk-theme-name=Stylix
-    EOF
-
-    cat >"$config/gtk-4.0/settings.ini" <<EOF
-    [Settings]
-    gtk-theme-name=Stylix
-    EOF
-
-    cat >"$theme/index.theme" <<EOF
-    [Desktop Entry]
-    Name=Stylix
-    Type=X-GNOME-Metatheme
-    Encoding=UTF-8
-
-    [X-GNOME-Metatheme]
-    GtkTheme=Stylix
-    EOF
+let
+  format = lib.generators.toINI { };
 
-    cat >"$theme/gtk-3.0/gtk.css" <<EOF
-    @import url('$parent/gtk-3.0/gtk.css');
-    @import url('$baseCss');
-    $extraCss
-    EOF
+  settings = writeText "stylix-gtk-settings.ini" (format {
+    Settings.gtk-theme-name = "Stylix";
+  });
 
-    cat >"$theme/gtk-3.0/gtk-dark.css" <<EOF
-    @import url('$parent/gtk-3.0/gtk-dark.css');
-    @import url('$baseCss');
-    $extraCss
-    EOF
-
-    ln --symbolic \
-      "$parent/gtk-3.0/assets" \
-      "$theme/gtk-3.0/assets"
-
-    cat >"$theme/gtk-4.0/gtk.css" <<EOF
-    @import url('$parent/gtk-4.0/gtk.css');
-    @import url('$baseCss');
-    $extraCss
-    EOF
+  index = writeText "stylix-gtk-index.theme" (format {
+    "Desktop Entry" = {
+      Encoding = "UTF-8";
+      Name = "Stylix";
+      Type = "X-GNOME-Metatheme";
+    };
+    X-GNOME-Metatheme.GtkTheme = "Stylix";
+  });
 
-    cat >"$theme/gtk-4.0/gtk-dark.css" <<EOF
-    @import url('$parent/gtk-4.0/gtk-dark.css');
-    @import url('$baseCss');
-    $extraCss
-    EOF
+  baseCss = colors {
+    template = ./gtk.css.mustache;
+    extension = ".css";
+  };
 
-    ln --symbolic \
-      "$parent/gtk-4.0/assets" \
-      "$theme/gtk-4.0/assets"
-  ''
+  css =
+    path:
+    writeText "stylix-gtk-${path}" ''
+      @import url('${adw-gtk3}/share/themes/adw-gtk3/${path}');
+      @import url('${baseCss}');
+      ${cfg.extraCss}
+    '';
+in
+linkFarm "stylix-gtk" [
+  {
+    name = "etc/xdg/gtk-3.0/settings.ini";
+    path = settings;
+  }
+  {
+    name = "etc/xdg/gtk-4.0/settings.ini";
+    path = settings;
+  }
+  {
+    name = "share/themes/Stylix/index.theme";
+    path = index;
+  }
+  {
+    name = "share/themes/Stylix/gtk-3.0/assets";
+    path = "${adw-gtk3}/share/themes/adw-gtk3/gtk-3.0/assets";
+  }
+  {
+    name = "share/themes/Stylix/gtk-3.0/gtk.css";
+    path = css "gtk-3.0/gtk.css";
+  }
+  {
+    name = "share/themes/Stylix/gtk-3.0/gtk-dark.css";
+    path = css "gtk-3.0/gtk-dark.css";
+  }
+  {
+    name = "share/themes/Stylix/gtk-4.0/assets";
+    path = "${adw-gtk3}/share/themes/adw-gtk3/gtk-4.0/assets";
+  }
+  {
+    name = "share/themes/Stylix/gtk-4.0/gtk.css";
+    path = css "gtk-4.0/gtk.css";
+  }
+  {
+    name = "share/themes/Stylix/gtk-4.0/gtk-dark.css";
+    path = css "gtk-4.0/gtk-dark.css";
+  }
+]