bw-skin-editor/build.gradle at master · kuroppoi/bw-skin-editor · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
plugins {
    id 'java'
}

project.ext {
    mainClass = 'io.github.kuroppoi.bwse.Main'
    workingDir = 'run'
}

repositories {
    mavenCentral()
}

dependencies {
    implementation 'com.formdev:flatlaf:3.5'
    implementation 'com.formdev:flatlaf-extras:3.5'
    implementation 'com.formdev:flatlaf-intellij-themes:3.5'
}

java {
    sourceCompatibility = JavaVersion.VERSION_17
    targetCompatibility = JavaVersion.VERSION_17
}

task dist(type: Jar) {
    manifest {
        attributes 'Main-Class': project.ext.mainClass, 'Multi-Release': 'true'
    }

    from {
        configurations.runtimeClasspath.collect {
            it.isDirectory() ? it : zipTree(it)
        }
    }

    archiveBaseName = 'BWSkinEditor'
    preserveFileTimestamps = false
    reproducibleFileOrder = true
    duplicatesStrategy = DuplicatesStrategy.EXCLUDE
    dependsOn configurations.runtimeClasspath
    with jar
}

task run(type: JavaExec) {
    mainClass = project.ext.mainClass
    workingDir = project.ext.workingDir
    classpath = sourceSets.main.runtimeClasspath

    doFirst {
        mkdir workingDir
    }
}