Initial code commit

Author: tkoeppe

BUILD

@@ -0,0 +1,3 @@
+licenses(["notice"])
+
+exports_files(["LICENSE"])

README.md

@@ -0,0 +1,57 @@
+# DeepMind Lab2D
+
+*A learning environment written in C++ and Lua for the creation of grid worlds.*
+
+<div align="center">
+<img src="docs/screenshot.png" alt="DeepMind Lab2D screenshot">
+</div>
+
+## About
+
+*DeepMind Lab2D* is a system for the creation of 2D environments for machine
+learning. The main goals of the system are ease of use and performance: The
+environments are "grid worlds", which are defined with a combination of simple
+text-based maps for the layout of the world, and Lua code for its behaviour.
+Machine learning agents interact with these environments through one of two
+APIs, the Python [`dm_env`](https://github.com/deepmind/dm_env) API or a custom
+C API (which is also used by [DeepMind Lab](https://github.com/deepmind/lab)).
+Multiple agents are supported.
+
+## Getting started
+
+We provide an example "random" agent in `python/random_agent`, which performs
+random actions. This can be used as a base for creating your own agents, and as
+a simple tool to preview an environment.
+
+```sh
+bazel run -c opt dmlab2d/python:random_agent -- --level_name=clean_up
+```
+
+## External dependencies, prerequisites and porting notes
+
+*DeepMind Lab2D* currently ships as source code only. It depends on a few
+external software libraries, which we ship in several different ways:
+
+ * The `dm_env`, `eigen`, `luajit`, `lua5.1`, `lua5.2`, `luajit`, `png`, `six`
+   and `zlib` libraries are referenced as external Bazel sources, and Bazel
+   BUILD files are provided. The dependent code itself should be fairly
+   portable, but the BUILD rules we ship are specific to Linux on x86. To build
+   on a different platform you will most likely have to edit those BUILD files.
+
+ * A "generic reinforcement learning API" is included in
+   [`//third_party/rl_api`](third_party/rl_api).
+
+ * Several additional libraries are required but are not shipped in any form;
+   they must be present on your system:
+
+   * `Python 2.7 or 3.6` or above with `NumPy` and `PyGame`. It is important
+     to update the paths to the Python version you are using by editing
+     [`bazel/python.BUILD`](bazel/python.BUILD).
+
+The build rules are using a few compiler settings that are specific to
+GCC/clang. If some flags are not recognized by your compiler (typically those
+would be specific warning suppressions), you may have to edit those flags.
+
+## Disclaimer
+
+This is not an official Google product.

build_defs.bzl

@@ -0,0 +1,111 @@
+# Copyright 2019 DeepMind Technologies Limited.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#    http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+# ============================================================================
+
+"""A BUILD rule for Python extensions that are defined via pybind11."""
+
+load("@bazel_skylib//lib:collections.bzl", "collections")
+
+def pybind_extension(
+        name,
+        deps = [],
+        data = [],
+        copts = [],
+        features = [],
+        module_name = None,
+        tags = [],
+        visibility = None,
+        **cc_kwargs):
+    """Creates a pybind11-based C++ library to extend Python.
+
+    Args:
+      name: A unique name for this target.
+      deps: The list of other libraries that the C++ target depends upon.
+      data: The list of files needed by this rule at runtime.
+      copts: Add these options to the C++ compilation command.
+      features: Modify the features currently enabled on the package level via
+          the `features` attribute.
+      module_name: The extension module's name, if it differs from the rule's name.
+          Must match the module name specified in the C++ source code, otherwise
+          it cannot be loaded by Python.
+      tags: A list of tags to be applied to all generated rules.
+      visibility: The visibility of all generated rules.
+      **cc_kwargs: Additional keyword arguments that are passed to a generated
+          `cc_binary` rule.
+
+    Returns:
+      A `py_library` rule.
+    """
+    pybind11_deps = [
+        "@pybind11_archive//:pybind11",
+        "@python_system//:python_headers",
+    ]
+    pybind11_copts = ["-fexceptions"]
+    pybind11_features = ["-use_header_modules"]
+
+    if module_name == None:
+        module_name = name
+
+    py_kwargs = dict()
+
+    if visibility != None:
+        for kwargs in (cc_kwargs, py_kwargs):
+            kwargs["visibility"] = visibility
+
+    shared_lib_name = module_name + ".so"
+    native.cc_binary(
+        name = shared_lib_name,
+        deps = collections.uniq(deps + pybind11_deps),
+        copts = collections.uniq(copts + pybind11_copts),
+        features = collections.uniq(features + pybind11_features),
+        tags = tags,
+        linkshared = 1,
+        linkstatic = 1,
+        **cc_kwargs
+    )
+
+    return native.py_library(
+        name = name,
+        data = data + [module_name + ".so"],
+        tags = tags,
+        **py_kwargs
+    )
+
+def pytype_strict_library(name, **kwargs):
+    native.py_library(name = name, **kwargs)
+
+def pytype_strict_binary(name, **kwargs):
+    native.py_binary(name = name, **kwargs)
+
+def py2and3_strict_test(name, **kwargs):
+    """A drop-in replacement for py_test that runs tests under both Py2 and Py3.
+
+    An invocation `py2and3_test(name = "foo_test", ...)` creates two actual test
+    targets foo.py2 and foo.py3, which set python_version respectively to "PY2"
+    and "PY3".
+
+    Args:
+      name: the rule name, which becomes the name of a test suite
+      **kwargs: forwarded to each py_test
+    """
+
+    py2 = name + ".py2"
+    py3 = name + ".py3"
+
+    main = kwargs.pop("main", name + ".py")
+    tags = kwargs.pop("tags", [])
+
+    native.py_test(name = py2, main = main, tags = tags, python_version = "PY2", **kwargs)
+    native.py_test(name = py3, main = main, tags = tags, python_version = "PY3", **kwargs)
+    native.test_suite(name = name, tags = tags, tests = [py2, py3])

dmlab2d/BUILD

@@ -0,0 +1,97 @@
+# Description:
+#   Lab2D ("dmlab2d") is a 2D multiplayer grid-world
+#   environment for machine learning.
+
+load("//dmlab2d/testing:lua_testing.bzl", "dmlab2d_lua_level_test", "dmlab2d_lua_test")
+
+licenses(["notice"])
+
+exports_files(["LICENSE"])
+
+cc_library(
+    name = "dmlab2d",
+    srcs = ["dmlab2d.cc"],
+    hdrs = ["dmlab2d.h"],
+    data = [
+        ":game_scripts",
+        "//dmlab2d/game_scripts/levels/chase_eat",
+        "//dmlab2d/game_scripts/levels/clean_up",
+        "//dmlab2d/game_scripts/levels/commons_harvest",
+        "//dmlab2d/game_scripts/levels/pushbox",
+        "//dmlab2d/game_scripts/levels/running_with_scissors",
+    ],
+    visibility = ["//visibility:public"],
+    deps = [
+        "//dmlab2d/env_lua_api",
+        "//dmlab2d/lua:bind",
+        "//dmlab2d/system/file_system/lua:file_system",
+        "//dmlab2d/system/generators/pushbox/lua:pushbox",
+        "//dmlab2d/system/grid_world/lua:lua_world",
+        "//dmlab2d/system/tile/lua:tile",
+        "//third_party/rl_api:env_c_api",
+        "//third_party/rl_api:env_c_api_bind",
+        "@com_google_absl//absl/memory",
+    ],
+)
+
+cc_test(
+    name = "dmlab2d_test",
+    srcs = ["dmlab2d_test.cc"],
+    deps = [
+        ":dmlab2d",
+        "//dmlab2d/util:test_srcdir",
+        "//third_party/rl_api:env_c_api",
+        "//third_party/rl_api:env_c_api_test_suite",
+        "@com_google_absl//absl/strings",
+        "@com_google_absl//absl/types:span",
+        "@com_google_googletest//:gtest_main",
+    ],
+)
+
+filegroup(
+    name = "game_scripts",
+    srcs = glob(
+        [
+            "game_scripts/**/*.lua",
+            "game_scripts/**/*.png",
+        ],
+        exclude = [
+            "game_scripts/**/*_test_data/*",
+            "game_scripts/**/*_test.lua",
+        ],
+    ),
+    visibility = ["//dmlab2d/lua_interp:__pkg__"],
+)
+
+TEST_SCRIPTS = [test[:-len(".lua")] for test in glob(["**/*_test.lua"])]
+
+test_suite(
+    name = "lua_tests",
+    tests = TEST_SCRIPTS,
+)
+
+[
+    dmlab2d_lua_test(name = test_script)
+    for test_script in TEST_SCRIPTS
+]
+
+# Find all directories containing file 'init.lua'.
+LEVEL_DIRS = [p[:-len("/init.lua")] for p in glob(["game_scripts/levels/**/init.lua"])]
+
+# Find single levels not in subdirectorys of LEVEL_DIRS
+SINGLE_LEVEL_SCRIPTS = [test[:-len(".lua")] for test in glob(
+    ["game_scripts/levels/**/*.lua"],
+    exclude = ["**/*_test.lua"] + [p + "/**/*.lua" for p in LEVEL_DIRS],
+)]
+
+LEVEL_SCRIPTS = SINGLE_LEVEL_SCRIPTS + [p + "/init" for p in LEVEL_DIRS]
+
+test_suite(
+    name = "lua_level_tests",
+    tests = LEVEL_SCRIPTS,
+)
+
+[
+    dmlab2d_lua_level_test(name = level_script)
+    for level_script in LEVEL_SCRIPTS
+]

dmlab2d/command_line_interface/BUILD

@@ -0,0 +1,20 @@
+# Description:
+#   Command line interface for profiling and inspecting different Lab2D environments.
+
+licenses(["notice"])
+
+cc_binary(
+    name = "command_line_interface",
+    srcs = ["command_line_interface_main.cc"],
+    visibility = ["//visibility:public"],
+    deps = [
+        "//dmlab2d",
+        "//third_party/rl_api:env_c_api",
+        "@com_google_absl//absl/flags:flag",
+        "@com_google_absl//absl/flags:parse",
+        "@com_google_absl//absl/flags:usage",
+        "@com_google_absl//absl/strings",
+        "@com_google_absl//absl/strings:str_format",
+        "@com_google_absl//absl/types:optional",
+    ],
+)