docs: add standalone distribution example

Author: JuroUhlar

.gitignore

@@ -38,3 +38,6 @@ terraform.rc
 
 # Ignore IDE
 .idea/
+
+# Ignore Terraform locks in examples folder
+examples/**/*.lock.hcl

examples/standalone-distribution/cloudfront_distribution.tf

@@ -0,0 +1,71 @@
+resource "aws_cloudfront_distribution" "fpjs_cloudfront_distribution" {
+  comment = "Fingerprint proxy integration distribution (created via Terraform)"
+
+  origin {
+    domain_name = module.fingerprint_cloudfront_integration.fpjs_origin_name
+    origin_id   = module.fingerprint_cloudfront_integration.fpjs_origin_id
+    custom_origin_config {
+      origin_protocol_policy = "https-only"
+      http_port              = 80
+      https_port             = 443
+      origin_ssl_protocols   = ["TLSv1.2"]
+    }
+    custom_header {
+      name  = "FPJS_SECRET_NAME"
+      value = module.fingerprint_cloudfront_integration.fpjs_secret_manager_arn
+    }
+  }
+
+  enabled = true
+
+  http_version = "http1.1"
+
+  price_class = "PriceClass_100"
+
+  default_cache_behavior {
+    allowed_methods          = ["GET", "HEAD", "OPTIONS", "PUT", "POST", "PATCH", "DELETE"]
+    cached_methods           = ["GET", "HEAD"]
+    cache_policy_id          = module.fingerprint_cloudfront_integration.fpjs_cache_policy_id
+    origin_request_policy_id = module.fingerprint_cloudfront_integration.fpjs_origin_request_policy_id
+    target_origin_id         = module.fingerprint_cloudfront_integration.fpjs_origin_id
+    viewer_protocol_policy   = "https-only"
+    compress                 = true
+
+    lambda_function_association {
+      event_type   = "origin-request"
+      lambda_arn   = module.fingerprint_cloudfront_integration.fpjs_proxy_lambda_arn
+      include_body = true
+    }
+  }
+
+
+
+  restrictions {
+    geo_restriction {
+      restriction_type = "none"
+    }
+  }
+
+  aliases = ["${var.subdomain}.${var.root_domain}"]
+  viewer_certificate {
+    acm_certificate_arn = "arn:aws:acm:us-east-1:013357491684:certificate/c3ffee8c-071b-4ff8-bec2-e222eff602bc"
+    ssl_support_method  = "sni-only"
+  }
+
+  # If don't want to serve the distribution from a subdomain for now, use the default certificate instead
+  # (comment out `viewer_certificate` and `aliases` above and use the `viewer_certificate` below)
+
+  # viewer_certificate {
+  #   cloudfront_default_certificate = true
+  # }
+}
+
+# You can make the distribution avaialable on a subdomain of your website
+# (comment this out if you don't want to do that for now)
+resource "aws_route53_record" "cloudfront_terraform_new_distribution_record" {
+  zone_id = var.domain_zone_id
+  name    = "${var.subdomain}.${var.root_domain}"
+  type    = "CNAME"
+  ttl     = 300
+  records = [aws_cloudfront_distribution.fpjs_cloudfront_distribution.domain_name]
+}

examples/standalone-distribution/fingerprint.tf

@@ -0,0 +1,9 @@
+module "fingerprint_cloudfront_integration" {
+  source = "[email protected]:fingerprintjs/terraform-aws-fingerprint-cloudfront-proxy-integration.git"
+
+  fpjs_agent_download_path = var.fpjs_agent_download_path
+  fpjs_get_result_path     = var.fpjs_get_result_path
+  fpjs_shared_secret       = var.fpjs_shared_secret
+}
+
+

examples/standalone-distribution/providers.tf

@@ -0,0 +1,14 @@
+terraform {
+  required_providers {
+    aws = {
+      source  = "hashicorp/aws"
+      version = "~> 5.57"
+    }
+  }
+
+  required_version = ">= 1.2.0"
+}
+
+provider "aws" {
+  region = "us-east-1"
+}

examples/standalone-distribution/variables.tf

@@ -0,0 +1,31 @@
+variable "fpjs_shared_secret" {
+  description = "The proxy secret for the Fingerprint proxy integration"
+  type        = string
+}
+
+variable "fpjs_agent_download_path" {
+  description = "The Fingerprint agent download will be proxied through this path"
+  type        = string
+}
+
+variable "fpjs_get_result_path" {
+  description = "The Fingerprint identification request will be proxied through this path"
+  type        = string
+}
+
+variable "subdomain" {
+  description = "The subdomain for the CloudFront distribution"
+  type        = string
+  # default   = "metrics"
+}
+
+variable "root_domain" {
+  description = "The root domain for the CloudFront distribution"
+  type        = string
+  # default     = "yourwebsite.com"
+}
+
+variable "domain_zone_id" {
+  description = "Zone ID of the domain for the CloudFront distribution"
+  type        = string
+}