LZ4 library don't accept options

[paulocoutinhox]

Hi,

I have a small problem here about LZ4 library.

Im passing the OPTIONS but it don't affect the library build, only if i put outside on CMakeLists.txt.

Example working:

set(BUILD_SHARED_LIBS OFF)
set(BUILD_STATIC_LIBS ON)
set(LZ4_BUILD_CLI OFF)
set(LZ4_BUILD_LEGACY_LZ4C OFF)
set(LZ4_BUNDLED_MODE OFF)

CPMAddPackage(
    NAME lz4
    GITHUB_REPOSITORY lz4/lz4
    VERSION 1.10.0
)

if (lz4_ADDED)
    add_subdirectory(${lz4_SOURCE_DIR}/build/cmake lz4_build)
endif()

target_link_libraries(bitchat
    spdlog::spdlog
    OpenSSL::SSL
    OpenSSL::Crypto
    lz4_static
)

Example don't working:

CPMAddPackage(
    NAME lz4
    GITHUB_REPOSITORY lz4/lz4
    VERSION 1.10.0
    OPTIONS
        "BUILD_SHARED_LIBS OFF"
        "BUILD_STATIC_LIBS ON"
        "LZ4_BUILD_CLI OFF"
        "LZ4_BUILD_LEGACY_LZ4C OFF"
        "LZ4_BUNDLED_MODE OFF"
)

if (lz4_ADDED)
    add_subdirectory(${lz4_SOURCE_DIR}/build/cmake lz4_build)
endif()

target_link_libraries(bitchat
    spdlog::spdlog
    OpenSSL::SSL
    OpenSSL::Crypto
    lz4_static
)

Can you help me?

[iboB]

The options would only apply if CPMAddPackage adds the subdirectory. By your code I assume the repo does not contain CMakeLists.txt at its root and thus is implicitly DOWNLOAD_ONLY. The options passed to CPMAddPackage cannot be applied in this case.

Instead set them like you do in the original example.

CPMAddPackage(
    NAME lz4
    GITHUB_REPOSITORY lz4/lz4
    VERSION 1.10.0
    # no options here
)

if (lz4_ADDED)
    # lz4 config options
	set(BUILD_SHARED_LIBS OFF)
	set(BUILD_STATIC_LIBS ON)
	set(LZ4_BUILD_CLI OFF)
	set(LZ4_BUILD_LEGACY_LZ4C OFF)
	set(LZ4_BUNDLED_MODE OFF)
    add_subdirectory(${lz4_SOURCE_DIR}/build/cmake lz4_build)
endif()

...