immer/flake.nix at master · arximboldi/immer · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
{
  description = "Immutable data structures";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-25.11";
    flake-utils.url = "github:numtide/flake-utils";
    nix-github-actions.url = "github:nix-community/nix-github-actions";
    nix-github-actions.inputs.nixpkgs.follows = "nixpkgs";
  };

  outputs =
    {
      self,
      nixpkgs,
      flake-utils,
      nix-github-actions,
    }:
    {
      githubActions = nix-github-actions.lib.mkGithubMatrix {
        checks = nixpkgs.lib.getAttrs [
          "x86_64-linux"
          "aarch64-linux"
          # "x86_64-darwin" not supported by GH Actions runners anymore
          "aarch64-darwin"
        ] self.checks;
      };
    }
    // flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = nixpkgs.legacyPackages.${system};
        lib = nixpkgs.lib;
        toolchains = [
          "gnu"
          "gnu-15"
          "gnu-14"
          "gnu-13"
          "llvm"
          "llvm-20"
          "llvm-19"
          "llvm-18"
        ];
      in
      {
        devShells = (
          with self.devShells.${system};
          {
            default = pkgs.callPackage ./shell.nix { };
          }
          // lib.attrsets.genAttrs toolchains (toolchain: default.override { inherit toolchain; })
        );

        checks = self.packages.${system};

        packages = (
          with self.packages.${system};
          {
            default = immer;

            immer = pkgs.callPackage nix/immer.nix { sources = ./.; };

            tests = immer.override {
              withTests = true;
              withExamples = true;
              withPersist = true;
            };
            tests-debug = tests.override {
              withDebug = true;
              withASan = true;
              withLSan = true;
            };

            fuzzers = immer.override {
              withFuzzers = true;
              withASan = true;
            };
            fuzzers-debug = fuzzers.override {
              withDebug = true;
            };
          }
          // pkgs.lib.optionalAttrs pkgs.stdenv.isLinux {
            tests-valgrind = tests.override {
              withDebug = true;
              withValgrind = true;
            };

            benchmarks = immer.override { withBenchmarks = true; };
          }
        );
      }
    );
}