WebClientSecure example

Author: JAndrassy

examples/WebClientSecure/WebClientSecure.ino

@@ -0,0 +1,100 @@
+/*
+  The classic Arduino WebClient Ethernet example
+
+ This sketch connects to a website (http://arduino.cc) using Ethernet.
+
+ created 18 Dec 2009
+ by David A. Mellis
+ modified 9 Apr 2012
+ by Tom Igoe, based on work by Adrian McEwen
+
+ */
+
+#include <EthernetESP32.h>
+#include <NetworkClientSecure.h>
+
+W5500Driver driver;
+//ENC28J60Driver driver;
+//EMACDriver driver(ETH_PHY_LAN8720);
+
+char server[] = "arduino.tips";
+
+// Set the static IP address to use if the DHCP fails to assign
+IPAddress ip(192, 168, 0, 177);
+
+// Initialize the Ethernet client library
+// with the IP address and port of the server
+// that you want to connect to (port 80 is default for HTTP):
+NetworkClientSecure client;
+
+void setup() {
+
+  Serial.begin(115200);
+  delay(500);
+  while (!Serial);
+
+  Ethernet.init(driver);
+
+  // start the Ethernet connection:
+  Serial.println("Initialize Ethernet with DHCP:");
+  if (Ethernet.begin() == 0) {
+    Serial.println("Failed to configure Ethernet using DHCP");
+    // Check for Ethernet hardware present
+    if (Ethernet.hardwareStatus() == EthernetNoHardware) {
+      Serial.println("Ethernet shield was not found.  Sorry, can't run without hardware. :(");
+      while (true) {
+        delay(1); // do nothing, no point running without Ethernet hardware
+      }
+    }
+    if (Ethernet.linkStatus() == LinkOFF) {
+      Serial.println("Ethernet cable is not connected.");
+    }
+    // try to configure using IP address instead of DHCP:
+    Ethernet.begin(ip);
+  } else {
+    Serial.print("  DHCP assigned IP ");
+    Serial.println(Ethernet.localIP());
+  }
+
+  Serial.print("connecting to ");
+  Serial.print(server);
+  Serial.println("...");
+
+  client.setInsecure(); // use only for a test!
+
+  // if you get a connection, report back via serial:
+  if (client.connect(server, 443)) {
+    Serial.print("connected to ");
+    Serial.println(client.remoteIP());
+    // Make a HTTP request:
+    client.println("GET /asciilogo.txt HTTP/1.1");
+    client.print("Host: ");
+    client.println(server);
+    client.println("Connection: close");
+    client.println();
+  } else {
+    // if you didn't get a connection to the server:
+    Serial.println("connection failed");
+  }
+}
+
+void loop() {
+  // if there are incoming bytes available
+  // from the server, read them and print them:
+  while (client.available()) {
+    char c = client.read();
+    Serial.write(c);
+  }
+
+  // if the server's disconnected, stop the client:
+  if (!client.connected()) {
+    Serial.println();
+    Serial.println("disconnecting.");
+    client.stop();
+
+    // do nothing forevermore:
+    while (true) {
+      delay(1);
+    }
+  }
+}